小弟我VFP编程一直是自学,不专业不正规,半调子。
以前解决grid表单点击排序一直是先绑定数据源，然后编写各字段的header的click事决。
后偶尔看到一个用Bindevent()函数解决的方法，一直在尝试，但不成功，还请坛中大神
百忙之中伸手拉小弟一把~~~  ：）

这是程序

主要部份：
** thisform.myClick 自定义表单方法，点击表格各栏目排序
LOCAL aCol[1], cmd
IF (AEVENTS(aCol,0) > 0)
    IF (VARTYPE(aCol[1])=="O") AND (PROPER(aCol[1].BaseClass)=="Header")
        cmd = "SELECT * FROM cp2013 ORDER BY " +;
            JUSTEXT(aCol[1].Parent.ControlSource) +;
            IIF(this.Ascending, " ASC ", " DESC ") +;
            "INTO CURSOR grid1_tmp"
        this.grid1.RecordSource = ""
        USE IN "grid1_tmp"
        EXECSCRIPT(cmd)
        this.grid1.RecordSource = "grid1_tmp"
        this.grid1.SetFocus
        this.Ascending = !this.Ascending &&自定义表单属性Ascending，升降序切换
    ENDIF
ENDIF

** thisform.Init
SELECT * FROM cp2013 INTO CURSOR grid1_tmp
this.grid1.recordsource = "grid1_tmp"
FOR EACH oColumn IN this.grid1.Columns
    BINDEVENT(oColumn.Header1, "Click", this, "myClick")
ENDFOR

多谢两位大神，够我学习消化一阵子的了。
因为是野路子，所以这个解决的思路不能理解，还请两大神不要见笑~

再次感谢，已经搞懂了~

正真的高手，学习了，谢谢

我以前在这个论坛上看到1个,在GRID标题栏上有个图片的,向上,向下的箭头

再请吹水大神看看，我按照大神给的代码变换了一下，但发生了一个错误,（临时表名）必须由select ...into table 创建
个人猜测：
错误应该是是this.RecordSource =mCursor产生的
因为默为的数据源是"别名",所以this.RecordSource =mCursor会认为是字段名
修改成
       mCmd="select *from "+mCursor+" order by "+mField+" into cursor "+mCursor
       this.recordsourcetype=4
       this.RecordSource =mCmd
      后倒是不报错了，但数据是空的
请教该如何解决

[此贴子已经被作者于2018-3-14 13:12编辑过]

试了一下 recordsourcetype=4 好象无什么异常

** thisform.myClick 自定义表单方法，点击表格各栏目排序
LOCAL aCol[1]
IF (AEVENTS(aCol,0) > 0)
    IF (VARTYPE(aCol[1])=="O") AND (PROPER(aCol[1].BaseClass)=="Header")
        this.grid1.RecordSource = "SELECT * FROM cp2013 ORDER BY " +;
            JUSTEXT(aCol[1].Parent.ControlSource) +;
            IIF(this.Ascending, " ASC ", " DESC ") +;
            "INTO CURSOR grid1_tmp READWRITE"
        this.grid1.SetFocus
        this.Ascending = !this.Ascending &&自定义属性Ascending，升降序切换
    ENDIF
ENDIF

** thisform.Init
this.grid1.RecordSourceType = 4
this.grid1.RecordSource = "SELECT * FROM cp2013 INTO CURSOR grid1_tmp READWRITE"
FOR EACH oColumn IN this.grid1.Columns
    BINDEVENT(oColumn.Header1, "Click", this, "myClick")
ENDFOR

吹版,在GRID的标题上用1个图片,显示当前的排序是向上还是向下的,怎么做.我以前看到有,忘了在哪里